www.chaturbate.com - HowTo record 100% free XXX/adult web-cam videos

[Infernos]

Now if only it was able to record the private shows too haha. Anyway, is there any reason why some videos have audio and others don't?

[PaDa]

if i start the chaturbateRex.exe it´s say "Enable to find ffmpeg" but its installed

[david00]

Originally Posted by PaDa

if i start the chaturbateRex.exe it´s say "Enable to find ffmpeg" but its installed

put ffmpeg.exe in the folder ChaturbateRec

[PaDa]

perfect thx.
so is there any ad on to record privat shows? ;-)

[alexiase]

Hi i'm new here
i've just installed chaturbaterec.
everything is ok
but i don't understand how i must list the models in the models.list

[ZeChico]

Originally Posted by alexiase

Hi i'm new here
i've just installed chaturbaterec.
everything is ok
but i don't understand how i must list the models in the models.list

Right mouse click on the program to add models, then right mouse again and select the option to save.

To manual edit, first you must put 0 or 1 to record and the rest is the model name, for example:
1model


I created a bat file to automatically record a specific model (loops each 30+ seconds), rtmpdump must be on the same folder, and the name of the bat must be the model name (ex model.bat), the save directory "savedir" should also be configured:

@echo off
set savedir=C:\CBsaves
set model=%~n0

:loop
set hour=%time:~0,2%
if "%hour:~0,1%" == " " set hour=0%hour:~1,1%
set min=%time:~3,2%
if "%min:~0,1%" == " " set min=0%min:~1,1%
set secs=%time:~6,2%
if "%secs:~0,1%" == " " set secs=0%secs:~1,1%

set year=%date:~-4%
set month=%date:~3,2%
if "%month:~0,1%" == " " set month=0%month:~1,1%
set day=%date:~0,2%
if "%day:~0,1%" == " " set day=0%day:~1,1%

set _my_datetime=%year%-%month%-%day%_%hour%-%min%-%secs%
echo -------- %_my_datetime% --------
echo Model: %model%
echo.

@set file=%savedir%\%_my_datetime%_%model%.flv
rtmpdump -r "rtmp://edge50-b.stream.highwebmedia.com/live-edge" -a "live-edge" -f "WIN 20,0,0,270" -W "https://chaturbate.com/static/flash/CBV_2p647.swf" -p "https://chaturbate.com/%model%/" -C S:AnonymousUser -C S:%model% -C S:2.646 -C S:anonymous -C S:37c7e09e2cdacc04afbed13f030bd8fa24ddd4ffd4bb70d0d6f8da9ee1627398 --live -y "mp4:rtmp://origin8.stream.highwebmedia.com/live-origin/%model%" -o "%file%"

call :setsize %file%
IF %size%==0 DEL %file%

@ping 192.0.2.2 -n 1 -w 30000 > nul

goto loop

:setsize
set size=%~z1
goto :eof

pause

[alexiase]

Thx a lot I've tried and it's ok
the anly thing now is that the ts file are big.
It would be nice when it's possible to change ts to flv directly in download instead of convert it afterward.

[ZeChico]

I changed the batch from using a static server to a random one, this should prevent errors when servers are full.

Once again, this is to be put on a bat file and will automatically record a specific model, loops each 30+ seconds (configurable), rtmpdump must be on the same folder, and the name of the bat must be the model name (ex model.bat), the save directory "savedir" should also be configured.

This is the new batch:

@ECHO OFF
SET savedir=C:\CBsaves
SET model=%~n0
SET /A looptime= 30 * 1000

:loop
SET hour=%time:~0,2%
IF "%hour:~0,1%" == " " SET hour=0%hour:~1,1%
SET min=%time:~3,2%
IF "%min:~0,1%" == " " SET min=0%min:~1,1%
SET secs=%time:~6,2%
IF "%secs:~0,1%" == " " SET secs=0%secs:~1,1%

SET year=%date:~-4%
SET month=%date:~3,2%
IF "%month:~0,1%" == " " SET month=0%month:~1,1%
SET day=%date:~0,2%
IF "%day:~0,1%" == " " SET day=0%day:~1,1%

SET _my_datetime=%year%-%month%-%day%_%hour%-%min%-%secs%
ECHO -------- %_my_datetime% --------
ECHO Model: %model%
ECHO.

SET file=%savedir%\%model%_%_my_datetime%.flv
call :rtmp

CALL :setsize %file%
IF %size%==0 DEL %file%

ping 192.0.2.2 -n 1 -w %looptime% > nul

GOTO loop

:rtmp

SET /A ser1=%random% %%50 + 5
SET /A ser2=%random% %%13 + 2
SET /A ser3=%random% %%2 + 1
IF %ser3% EQU 1 (SET ser3=a) ELSE (SET ser3=b)

ECHO Using RTMPdump with:
ECHO "rtmp://edge%ser1%-%ser3%.stream.highwebmedia.com/live-edge"
ECHO "mp4:rtmp://origin%ser2%.stream.highwebmedia.com/live-origin/%model%"
ECHO:
rtmpdump -r "rtmp://edge%ser1%-%ser3%.stream.highwebmedia.com/live-edge" -a "live-edge" -f "WIN 20,0,0,267" -W "https://chaturbate.com/static/flash/CBV_2p647.swf" -p "https://chaturbate.com/%model%/" -C S:AnonymousUser -C S:%model% -C S:2.646 -C S:anonymous -C S:8f034c5320f2d277c18d2c60da29eb8d2201d933ad843e38d87df9dc3ff26150 --live -y "mp4:rtmp://origin%ser2%.stream.highwebmedia.com/live-origin/%model%" -o "%file%"

GOTO :eof

:setsize
SET size=%~z1
GOTO :eof

Regards.

[alexiase]

thx a lot


with your bat, this mean i need to launch a bat per model isn't it?

[ZeChico]

Originally Posted by alexiase

thx a lot


with your bat, this mean i need to launch a bat per model isn't it?

Yes, but it's possible to create a bat file to start many more bat files, something like:

start /min model1.bat
start /min model2.bat
start /min model3.bat

(/min is to start minimized)

To not create new windows for each model and stay on only one console window:
EDIT: This won't work because on the same console windows all the parameter will mix up.

START /B /min CMD /C CALL model1.bat
START /B /min CMD /C CALL model2.bat
START /B /min CMD /C CALL model3.bat


ChaturbateRec can be more practical to use and records in TS instead of FLV, which is better to seek and see if the file is worth to keep or convert to mp4.
But ChaturbateRec doesn't seems to be very reliable, some records stutter and are useless.

To create a new bat for a new model, just copy & paste any bat (that records) and rename it with the new model to record.

Now that we are at it, this is other batch to convert FLV to MP4, will convert any flv on the same folder to mp4, will delete any flv with 2MB or less, and if the convertion to MP4 was successfull will delete the original flv.
ffmpeg must be on the same folder, or the path to ffmpeg must be added.

@ECHO OFF

FOR %%A IN (*.flv) DO (
          CALL :FIX "%%A"
)
GOTO END

:FIX
ECHO -------------------------------------------------------

call :setsize %1
IF %size% LSS 2097152 (
	DEL %1
	ECHO -------------------------------------------------------
	ECHO:
	ECHO %1
	ECHO Too small, deleted!
	ECHO:

GOTO :eof
)

SET output=%1
SET output=%output:~0,-4%mp4"

ECHO Converting to MP4...
ffmpeg.exe -i %1 -strict experimental -c:v copy -c:a libvo_aacenc -ab 16k -ar 16000 -ac 1 %output%

call :setsize %output%
IF %size% LSS 4096 (DEL %output%) ELSE (DEL %1)

ECHO -------------------------------------------------------
ECHO(
ECHO %1
ECHO Done!
ECHO(

GOTO :eof

:setsize
SET size=%~z1
GOTO :eof

:END
ECHO -------------------------------------------------------
ECHO:
ECHO All done!
ECHO ON
@PAUSE

Regards!