[ZeChico]

For those who use MFCRecorder and have many folders from models on the recording folder and are anoyed to have to seek all those folders to see the recordings, I have created a batch file to help.

Put this code on a bat (ex: "_Move.bat") in the "Recordings" folder, this will move any TS (not in use/record) into the "Recordings" folder.

@ECHO OFF

FOR /D %%D IN (*) DO (
	FOR %%F IN ("%%D"\*.ts) DO (
		IF "%%D" NEQ "OK" (
			ECHO -----------------------------------------------------------------------------
			ECHO "%%~nxF"
			move "%%~fF" "%~dp0"
		)
	)
)

ECHO All done!
pause

Then I have a folder called "OK" that I put all the TS that I want to convert to MP4.

Then use this other batch to convert all TS to MP4, this must be on the OK folder, will delete the original TS file if the convertion to MP4 was successfull, ffmpeg must be on the same folder or the path must be added.
The destination for the MP4 can also be edited (change "." in savedir for the destination folder).

@ECHO OFF

SET savedir=.
FOR %%A IN (*.ts) DO (
CALL :CONVERT "%%A"
)
GOTO END

:CONVERT
ECHO -------------------------------------------------------
ECHO - Converting %1...
SET input=%1
SET input=%input:~1%
SET output=%savedir%\%input%
SET output="%output:~0,-3%mp4"

ECHO Converting to MP4...
ffmpeg.exe -i %1 -strict experimental -c copy -bsf:a aac_adtstoasc %output%


call :setsize %output%
IF %size% LSS 2048 (
	DEL %output%
	ECHO:
	ECHO %output%
	ECHO:
	ECHO Convertion failed!
	ECHO:
	GOTO :eof
) ELSE (
	DEL %1
	ECHO:
	ECHO %output%
	ECHO:
	ECHO Convertion done!
	ECHO:
	GOTO :eof
)

:setsize
SET size=%~z1
GOTO :eof

:END
ECHO -------------------------------------------------------
ECHO:
ECHO All done!
ECHO ON

@PAUSE